Как управлять IContextMenu, часть 7 - вызов пункта меню по-умолчанию

Это перевод How to host an IContextMenu, part 7 - Invoking the default verb. Автор: Реймонд Чен.

Когда мы в последний раз оставили нашего героя, мы задумывались, как же вызвать действие по-умолчанию программно. Теперь, когда мы узнали так много про интерактивный случай с IContextMenu, мы можем использовать эту информацию для работы в полностью невизуальном случае.

Ключевой момент здесь - использование описателя HMENU для идентификации пункта меню по-умолчанию и просто прямой его вызов. Вернитесь к программке из пункта 1 и сделайте такие изменения:

procedure TForm1.FormContextPopup(Sender: TObject; MousePos: TPoint;
  var Handled: Boolean);
var
  pcm: IContextMenu;
  Menu: HMENU;
  Info: TCMInvokeCommandInfo;
  Id: UINT;
begin
  Handled := True;

  if SUCCEEDED(GetUIObjectOfFile(Handle, 'C:\Windows\clock.avi', IID_IContextMenu, pcm)) then
  try
    Menu := CreatePopupMenu;
    if Menu <> 0 then
    try
      if SUCCEEDED(pcm.QueryContextMenu(Menu, 0, SCRATCH_QCM_FIRST, SCRATCH_QCM_LAST, CMF_NORMAL)) then
      begin
        Id := GetMenuDefaultItem(Menu, 0, 0);
        if Id <> UINT(-1) then
        begin
          FillChar(Info, SizeOf(Info), 0);
          Info.cbSize := SizeOf(info);
          Info.hwnd := Handle;
          Info.lpVerb := MAKEINTRESOURCEA(Id - SCRATCH_QCM_FIRST);
          SetLastError(pcm.InvokeCommand(Info));
          if GetLastError <> 0 then
            RaiseLastOSError;
        end;
      end;
    finally
      DestroyMenu(Menu);
    end;
  finally
    pcm := nil;
  end;
end;

Мы добавили вызов функции GetMenuDefaultItem для получения элемента по-умолчанию и установку действия (verb) в форме смешения идентификатора меню (т.е. мы вычитаем начальную точку, которую мы передали в IContextMenu.QueryContextMenu).

Этот код работает, но его можно улучшить. В следующий раз, мы сделаем небольшое улучшение, которое улучшает производительность.