Что такое указатель статической цепочки в контексте соглашения о вызовах ABI?

Это перевод What is a static chain pointer in the context of calling convention ABI? Автор: Реймонд Чен.

Глубоко в руководстве Application Binary Interface из System V для архитектуры AMD64 есть сноска на странице 24, в которой говорится: "%r10 используется для передачи указателя статической цепочки функции". Что такое "указатель статической цепочки"?

Некоторые языки (например, Паскаль/Delphi) поддерживают вложенные функции. Вложенной функции может быть разрешен доступ к переменным родительской функции. Например:

function Outer(n: Integer): Integer;
var
  i: Integer;

  procedure Inner(m: Integer);
  begin
    i := i + m;
  end;

// Тут начинаяется функция Outer
begin
  i := 0;
  Inner(n);
  Result := i;
end;

Функция Outer не делает ничего полезного, но она не делает это ничего интересным образом.

Она начинается с объявления локальной переменной i, а затем определяет локальную функцию Inner, которая добавляет свой параметр m к внешней переменной i. Затем идёт код самой функции Outer, который начинается с инициализации i нулём, вызывает Inner(n) (которая добавляет n к i), а затем возвращает изменённое значение i.

По сути, функция Outer просто возвращает свой аргумент, но она делает это с помощью внутренней функции.

Это работает так: функция Inner получает скрытый параметр, который сообщает ей, где находятся локальные переменные процедуры Outer.

На практике передается указатель на кадр стека внешней функции.

А если внешняя функция сама по себе является вложенной, вы можете использовать родительский фрейм для доступа к локальным переменным "дедушки":

function Outer(n: Integer): Integer;
var
  i: Integer;

  procedure Inner(m: Integer);
  
    procedure MoreInner;    
    begin              
      i := i + m;
    end;
    
  begin
    MoreInner;
  end;

// Тут начинаяется функция Outer
begin
  i := 0;
  Inner(n);
  Result := i;
end;

В этом примере функция MoreInner получает скрытый указатель на кадр стека функции Inner, что позволяет ей получить доступ к параметру m из Inner. Но Inner сама по себе является вложенной процедурой - и поэтому она тоже получила указатель на кадр стека родителя (в данном случае - Outer). Следовательно, MoreInner может использовать этот указатель для доступа к локальной переменной i функции Outer.

Вот как это выглядит:

MoreInner		Inner		Outer
указатель цепочки	➝	указатель цепочки	➝	n
		m		i

Это называется статической цепочкой, поскольку структура цепочки основана на лексической, а не динамической области видимости. Вы можете увидеть разницу в этом примере:

function Outer(n: Integer): Integer;
var
  i: Integer;

  procedure Update(j: Integer);
  begin
    i := i + j;
  end;

  procedure Inner(m: Integer);

    procedure MoreInner;
    begin
      Update(m);
    end;

  // Тело функции Inner
  begin
    MoreInner;
  end;

// Тут начинается функция Outer
begin
  i := 0;
  Inner(n);
  Result := i;
end;

Эта версия еще более бесполезна, чем предыдущая: MoreInner не обновляет i напрямую, а вместо этого просит Update (функцию-"дядю") сделать это.

В тот момент, когда функция MoreInner вызывает Update, она не передает свой собственный кадр стека в качестве указателя статической цепочки. Вместо этого она передает кадр стека Outer, поскольку родительским элементом Update является Outer.

Статическая цепочка не соответствует динамическому стеку вызовов: стек вызовов говорит, что вызывающий объект функции Update — функция MoreInner, но статическая цепочка говорит, что родительским объектом Update является функция Outer:

Update		MoreInner		Inner		Outer
указатель фрейма	➝	указатель фрейма	➝	указатель фрейма	➝	указатель фрейма
указатель цепочки						n
		указатель цепочки	➝	указатель цепочки	⭧	i
				m

Авторы руководства Application Binary Interface предполагают, что вы знакомы с тем, как реализованы вложенные функции, и просто отмечают, что соглашение о вызове вложенных функций заключается в передаче статической цепочки в регистре %r10.